Treinamento Excell - Função CONT.SE

 CONT.SE (Função CONT.SE)

Excel do Microsoft 365 Excel do Microsoft 365 para Mac Excel para a Web

Use CONT.SE, uma das funções estatísticas, para contar o número de células que atendem a um critério; por exemplo, para contar o número de vezes que uma cidade específica aparece em uma lista de clientes.

Na forma mais simples, a função CONT.SE informa:

• =CONT.SE(Onde você quer procurar?; O que você quer procurar?)

Por exemplo:

• =CONT.SE(A2:A5;"Londres")

• =CONT.SE(A2:A5;A4)

• 
  

  CONT.SE(intervalo; critério)

  Nome do argumento	Descrição
  intervalo    (obrigatório)	O grupo de células que você deseja contar. O Intervalo pode conter números, matrizes, um intervalo nomeado ou referências que contenham números. Valores em branco e de texto são ignorados. Saiba como selecionar intervalos em uma planilha.
  critérios    (obrigatório)	Um número, expressão, referência de célula ou cadeia de texto que determina quais células serão contadas. Por exemplo, você pode usar um número como 32, uma comparação, como "> 32", uma célula como B4 ou uma palavra como "maçãs". CONT.SE usa apenas um único critério. Use CONT.SES se você quiser usar vários critérios.

  Exemplos

  Para usar estes exemplos no Excel, copie os dados na tabela abaixo e cole-os na célula A1 de uma nova planilha.

  Dados	Dados
  maçãs	32
  laranjas	54
  pêssegos	75
  maçãs	86
  Fórmula	Descrição
  =CONT.SE(A2:A5;"maçãs")	Conta o número de células com maçãs nas células A2 a A5. O resultado é 2.
  =CONT.SE(A2:A5;A4)	Conta o número de células com pêssegos (o valor de A4) nas células A2 a A5. O resultado será 1.
  =CONT.SE(A2:A5;A2)+CONT.SE(A2:A5;A3)	Conta o número de maçãs (o valor de A2) e laranjas (o valor de A3) nas células A2 a A5. O resultado será 3. Essa fórmula usa a função CONT.SE duas vezes para especificar vários critérios, sendo um critério por expressão. É possível também usar a função CONT.SES.
  =CONT.SE(B2:B5;">55")	Conta o número de células com um valor maior do que 55 nas células B2 a B5. O resultado é 2.
  =CONT.SE(B2:B5;"<>"&B4)	Conta o número de células com um valor não igual a 75 nas células B2 a B5. O E comercial (&) mescla o operador de comparação de "não é igual a" (<>) e o valor em B4 para ler =CONT.SE(B2:B5;"<> 75"). O resultado é 3.
  =CONT.SE(B2:B5;">=32")-CONT.SE(B2:B5;">85")	Conta o número de células com um valor maior (>) ou igual a (=) 32 e menor ou igual a 85 nas células B2 a B5. O resultado é 3.
  =CONT.SE(A2:A5;"*")	Conta o número de células contendo qualquer texto nas células A2 a A5. O asterisco (*) é usado como caractere curinga para corresponder a qualquer caractere. O resultado é 4.
  =CONT.SE(A2:A5;"?????es")	Conta o número de células que têm exatamente sete caracteres e que terminam com as letras "es" nas células A2 a A5. O ponto de interrogação (?) é usado como caractere curinga para corresponder a caracteres individuais. O resultado será 2.

  Problemas comuns

  Problema	O que deu errado
  Valor errado retornado para cadeias de caracteres longas.	A função CONT.SE retorna valores incorretos quando você a utiliza para corresponder cadeias de caracteres com mais de 255 caracteres. Para corresponder cadeias de caracteres de mais de 255 caracteres, use a função CONCATENAR ou o operador de concatenação &. Por exemplo, =CONT.SE (A2:A5, "texto longo" & "outra cadeia longa").
  Nenhum valor retorna quando você espera um valor.	Coloque o argumento critérios entre aspas.
  Uma fórmula CONT.SE recebe um erro #VALOR! ao se referir a outra planilha.	Este erro ocorre quando a fórmula que contém a função se refere a células ou a um intervalo em uma pasta de trabalho fechada e as células são calculadas. Para que esse recurso funcione, outra pasta de trabalho deverá estar aberta.

  Práticas recomendadas

  Faça isto	Por quê?
  Lembre-se de que CONT.SE ignora maiúsculas e minúsculas em cadeias de texto.	Critérios não fazem distinção entre maiúsculas e minúsculas. Em outras palavras, a cadeia "maçãs" e a cadeia "MAÇÃS" corresponderão às mesmas células.
  Use caracteres curinga.	Caracteres curinga (o ponto de interrogação (?) e o asterisco (*)) podem ser usados em critérios. Um ponto de interrogação determina qualquer caractere simples. Um asterisco determina qualquer sequência de caracteres. Se você quiser localizar um ponto de interrogação ou asterisco real, digite um til (~) antes do caractere. Por exemplo, =CONT.SE(A2:A5;"maçã?") contará todas as instâncias de "maçã" com uma última letra poderia variar.
  Verifique se seus dados não contêm caracteres equivocados.	Ao contar valores de texto, verifique se os dados não contêm espaços à esquerda, à direita, se usam de modo inconsistente as aspas normais e as curvas ou têm caracteres não imprimíveis. Nesses casos, a função CONT.SE poderá retornar um valor inesperado. Tente usar a função TIRAR ou a função ARRUMAR.
  Para sua conveniência, use intervalos nomeados	COUNTIF dá suporte a intervalos nomeados em uma fórmula (como =COUNTIF(fruit">=32")-COUNTIF(fruit">85"). O intervalo nomeado pode estar na planilha atual, em outra planilha na mesma pasta de trabalho ou ser proveniente de outra pasta de trabalho. Para fazer referência a outra pasta de trabalho, essa segunda pasta de trabalho também deve estar aberta.